screen tutorial_phone_main(location):

    frame:
        # Settings for the frame
        background None
        anchor(0.5, 0.5)
        pos(0.5, 0.5)

        at location

        # Background
        add "./phone/backgrounds/phone_background_space.png" anchor (0.5, 0.5) pos(0.5, 0.5)

        # List the main apps
        grid 3 3:
            xanchor 0.5
            yanchor 0.5
            xpos 0.5
            ypos 0.35
            spacing 32

            add "./phone/apps/app_map/app_map_icon_idle.png"
            add "./phone/apps/app_date/app_date_icon_idle.png"
            add "./phone/apps/app_calendar/app_calendar_icon_idle.png"
            add "./phone/apps/app_default_idle.png"
            add "./phone/apps/app_default_idle.png"
            add "./phone/apps/app_default_idle.png"
            add "./phone/apps/app_default_idle.png"
            add "./phone/apps/app_default_idle.png"
            add "./phone/apps/app_default_idle.png"

        # List the bottom row apps
        grid 3 1:
            xanchor 0.5
            yanchor 0.5
            xpos 0.5
            ypos 0.8125
            spacing 32

            imagebutton auto "./phone/apps/app_default_%s.png" action NullAction()
            imagebutton auto "./phone/apps/app_default_%s.png" action NullAction()
            imagebutton auto "./phone/apps/app_default_%s.png" action NullAction()

        # Phone outer case
        add "./phone/phone_case.png" anchor (0.5, 0.5) pos(0.5, 0.5)

screen tutorial_phone_map:

    frame:
        # Settings for the frame
        background None
        anchor(0.5, 0.5)
        pos(0.5, 0.5)

        # Map Background
        add "./phone/apps/app_map/app_map_background.png" anchor(0.5, 0.5) pos(0.5, 0.5)

        # For every location
        for i in range(len(locations)):

            $ location = locations[i]

            # Add a marker and test with the location name
            add "./phone/apps/app_map/app_map_waypoint_idle.png" anchor(0.5, 0.5) pos(location.position[0], location.position[1])
            text location.name anchor(0.5, 0.5) pos(location.position[0], location.position[1] - 0.06)

        # Phone outer case
        add "./phone/phone_app_case.png" anchor (0.5, 0.5) pos(0.5, 0.5)

screen tutorial_phone_calendar:

    # Phone Background
    add "./phone/backgrounds/phone_app_background_space.png" xanchor 0.5 yanchor 0.5 xpos 0.5 ypos 0.5

    # Current Day
    text "Day " + str(currentDay + 1) size 40 color "#FFFFFF" anchor(0.5, 0.5) pos(0.5, 0.2)

    # Display Events
    grid 4 1:
        anchor(0.5, 0.5)
        pos(0.5, 0.5)
        spacing 16

        # For each event...
        for i in range(4):

            # Set the temporary event
            $ temp = getEvent(i)

            # Begin creating the block
            frame:
                padding(0.0, 0.0)
                xysize(250, 200)

                # Text
                if(temp == None):
                    text "Nothing" size 20 color "#FFFFFF" anchor(0.5, 0.5) pos(0.5, 0.5)
                else:
                    text temp.name size 20 color "#FFFFFF" anchor(0.0, 0.0) pos(0.05, 0.05)
                    text "At " + temp.where size 16 color "#A9A9A9" anchor(0.0, 0.0) pos(0.05, 0.175)

                    text "With " + temp.who size 20 color "#FFFFFF" anchor(0.0, 0.0) pos(0.05, 0.3)
                    text "From " + temp.when_start + " - " + temp.when_end size 16 color "#A9A9A9" anchor(0.0, 0.0) pos(0.05, 0.425)

                    if temp.completed:
                        add "./phone/apps/app_calendar/app_calendar_event_completed.png" anchor(1.0, 1.0) pos(1.0, 1.0)
                    else:
                        add "./phone/apps/app_calendar/app_calendar_event_incompleted.png" anchor(1.0, 1.0) pos(1.0, 1.0)

    # Phone outer case
    add "./phone/phone_app_case.png" anchor (0.5, 0.5) pos(0.5, 0.5)
