
default tax_ship = map_click("Tax ship", (1169,613), action = None, image = "spanish_cargo")


define redteeth = Character("Cpt. Red teeth")
define wilson = Character("Wilson")
define crew = Character("Crew")
define me = Character("Me")

label intro:
    scene black
    show bg ship with dissolve
    show red_teeth with dissolve
    redteeth "A stowaway?"
    show red_teeth at midright with move
    show wilson at midleft with moveinleft
    wilson "Can I carve him now Captain?"
    redteeth "Patience Wilson."
    redteeth "Let's give the boy a chance."
    redteeth "What's your name boy?"
    me "Jack."
    redteeth "Jack huh?"
    redteeth "So... Jack... "
    redteeth "Is there any reason I should stop Wilson here from carving you up to shark bait?"
    me "I..."
    redteeth "Got a reach dad?"
    me "No."
    redteeth "He's yours Wilson."
    hide red_teeth with moveoutright
    show wilson at center with move
    wilson "Aye captain."
    me "WAIT!"
    show red_teeth at midright with moveinright
    show wilson at midleft with move
    redteeth "Remembered anything? A stash of gold perhaps?"
    me "I want to join you."
    redteeth "We're not hiring dead weight boy."
    me "I can be useful."
    redteeth "How?"
    me "I know of a very expensive cargo's position."
    wilson "He's lying."
    me "I'm not."
    redteeth "Go tend get the crew ready Wilson."
    wilson "Aye captain."
    hide wilson with moveoutleft
    show red_teeth at center with move
    me "It's a spanish ship."
    me "There aren't many guards on the ship either."
    redteeth "Really?"
    show map_background with dissolve
    show screen map_screen
    redteeth "Show me on this map."
    $ the_corridor.add(tax_ship)
    me "It's here..."
    $ the_corridor.add(pink_peaks)
    me "Near the pink peaks."
    hide map_background
    hide screen map_screen
    with dissolve
    redteeth "That's an odd place for a cargo ship."
    me "It's collecting tax."
    redteeth "Tax?"
    redteeth "Sounds dangerous."
    me "They left most of their men in my village."
    redteeth "Against my better judgment, I'm going to trust you boy."
    redteeth "Disappoint me and I'll leave you to Wilson."
    me "I won't captain."
    redteeth "Alright, lead the way boy."
    $ tax_ship.action = Jump("attacking_tax_ship")
    jump map

label attacking_tax_ship:
    call screen battle(tax_ship)
    $ the_corridor.remove(tax_ship)

    if _return == "lost":
        "Nobody rescues a pirate, you've perished in the sea."
        return
    
    scene bg ship with dissolve
    show red_teeth with dissolve
    if _return == "ran":
        redteeth "COMMANDING MY CREW?"
        redteeth "WHO DO YOU THINK YOU ARE BOY?"
        redteeth "BRING THE PLANK."
        me "NO!"
        redteeth "Do you prefer me calling Wilson?"
        me "Plank is fine."
        "You have walled the plank."
        "Nobody rescues a pirate, you've perished in the sea."
        return

    redteeth "You didn't mention the canons boy."
    redteeth "Did you try to kill us?"
    me "No!"
    me "They didn't have enough men to use all of them."
    redteeth "Right, right."
    redteeth "You have a keen eye for these things."
    redteeth "How do you like to do it again?"
    me "Do you mean?"
    redteeth "A position have opened on my ship."
    redteeth "The... map boy."
    me "Navigation master?"
    redteeth "Sure... You have to earn the master part though."
    redteeth "BRING HIM THE MAP."
    crew "Aye captain."
    show map_background with dissolve
    show screen map_screen
    redteeth "Where to next?"
    menu:
        "The old bay.":
            me "I need some some gossip."
            $ the_corridor.add(old_bay)
            me "Let's go to booty bay."
        "The shop needs fixing.":
            me "The shop needs fixing."
            me "I know the place."
            me "And it's nearby."
            me "Let's go to pink peaks."
    $ old_bay.action = Jump("old_bay")
    $ pink_peaks.action = Jump("pink_peaks")
    jump map
